+- Juergens-Workshops.de Forum (https://forum.juergens-workshops.de)
+-- Forum: Corel Grafik Forum (https://forum.juergens-workshops.de/forumdisplay.php?fid=65)
+--- Forum: Corel Draw (https://forum.juergens-workshops.de/forumdisplay.php?fid=93)
+--- Thema: Automatische aktuelle Datumsangabe (/showthread.php?tid=34232)
RE: Automatische aktuelle Datumsangabe - koter - 07.09.2024
Hallo Siggi,
(05.09.2024, 12:08)siggimitbart schrieb: ...Wäre es dann möglich, das in der Befehlsleiste oben als ICON zum draufklicken zu haben...
Ja, unter: -->Extras-->Optionen-->Anpassung-->Befehle-->Makros
kannst Du Dein Makro in eine Symbolleiste ziehen.
Ein Icon kannst Du dort erstellen oder importieren.
Du kannst auch einen Tastaturbefehl festlegen.
![[Bild: symbolleiste.jpg]](https://i.postimg.cc/P5PjjV90/symbolleiste.jpg)
(05.09.2024, 14:32)siggimitbart schrieb: Ich habe mal einen Code gemacht der tut auch das was er soll.
Nur möchte ich eigentlich nicht in das Dialogfeld "Export" sondern in den Dialog "Als PDF ausgeben"...
...Warum tut sich corel mit PublishToPdf so schwer?...
Zwei Bemerkungen vorab:
Dim shape As shape solltest Du nie schreiben!
Shape ist ein Objekttyp und sollte nie als Variable verwendet werden.
Das könnte sich schädlich auswirken!
Du hast die Variable currentDate deklariert, belegt und dann nicht verendet.
Das ist nicht schädlich aber sinnlos.
Der Befehl PublishToPdf erwartet nur einen Parameter, in Deinem Code stehen aber drei.
Das verursacht einen Fehler.
Ich habe Deinen Code geändert, so sollte er funktionieren:
Code:
Sub UpdateDateAndExport2()
Dim PDFEinst As PDFVBASettings
Dim currentDate As String, PDFName As String, FormatString As String
Dim x As Shape
Dim ds() As String
If Documents.Count < 1 Then Exit Sub 'Abbrechen falls kein Dokument vorhanden ist
Set PDFEinst = ActiveDocument.PDFSettings
' Aktuelles Datum im Format "DD.MM.YY"
currentDate = Format(Date, "DD.MM.YY")
' Alle Formen im Dokument durchlaufen
For Each x In ActiveDocument.SelectableShapes
' Überprüfen, ob die Form den Namen "DatumHeute" hat
If x.Name = "DatumHeute" Then
x.Text.Story = currentDate
ElseIf Left(x.Name, 10) = "DatumHeute" Then ' Überprüfen, ob der Name der Form mit "DatumHeute" beginnt
ds = Split(x.Name, "(")
FormatString = Left(ds(1), Len(ds(1)) - 1)
x.Text.Story = Format$(Date, FormatString)
FormatString = ""
End If
Next
' Dokument speichern
ActiveDocument.Save
PDFName = DateiDialog
If PDFName = "" Then Exit Sub 'Abbrechen falls kein Name übergeben wurde
If Not PDFEinst.ShowDialog Then Exit Sub 'Abbrechen falls Abbrechen gewählt wurde
ActiveDocument.PublishToPDF PDFName
End Sub
Function DateiDialog() As String
Dim CST As CorelScriptTools
Dim CDRN As String, DN As String, RN As String
Dim Antw
Set CST = CorelScriptTools
DN = ActiveDocument.Name
DN = Left(DN, Len(DN) - 3) & "pdf"
RN = CST.GetFileBox("(PDF)|*.pdf", "Als PDF freigeben", 1, DN)
If Len(RN) < 1 Then DateiDialog = RN: Exit Function
If Len(Dir(RN)) > 0 Then
Antw = MsgBox("Soll die bestehende Datei überschrieben werden?", vbQuestion + vbYesNo, "Datei überschreiben")
DateiDialog = ""
If Antw = vbYes Then
DateiDialog = RN
End If
Else
DateiDialog = RN
End If
End FunctionIch habe mir erlaubt Deine Kommentare zu korrigieren und zu ergänzen.
Die Funktion DateiDialog legt den Namen für die PDF im Dialog fest.
Falls Du immer die selben Daten verwendest, kannst Du sie auch fest programmieren.
Dann könntest Du Dir einen oder beide Dialoge sparen.
Gruß
Koter
RE: Automatische aktuelle Datumsangabe - siggimitbart - 12.09.2024
Hey klasse - das funktioniert!
DANKE!
Nun habe ich noch einen Korrekturwunsch.
Das Datum wird nur auf der aktuell geöffneten Seite geändert.
Wir arbeiten allerdings mit Dokumenten mit mehreren Seiten.
Es sollte dann auf allen Seiten gleichzeitig geändert werden.
Ist das möglich?
Vielen Dank!
RE: Automatische aktuelle Datumsangabe - koter - 13.09.2024
Hallo Siggi,
Mit einer kleinen Ergänzung sollte es möglich sein, alle Seiten zu bearbeiten:
Code:
Sub UpdateDateAndExport3()
Dim PDFEinst As PDFVBASettings
Dim currentDate As String, PDFName As String, FormatString As String
Dim x As Shape
Dim S As Page
Dim xR As ShapeRange, xRall As New ShapeRange
Dim ds() As String
If Documents.Count < 1 Then Exit Sub 'Abbrechen falls kein Dokument vorhanden ist
Set PDFEinst = ActiveDocument.PDFSettings
' Aktuelles Datum im Format "DD.MM.YY"
currentDate = Format(Date, "DD.MM.YY")
For Each S In ActiveDocument.Pages 'Auf allen Seiten suchen
Set xR = S.Shapes.FindShapes(Query:="@com.name.StartsWith('DatumHeute')")
xRall.AddRange xR
Next
For Each x In xRall
' Überprüfen, ob die Form den Namen "DatumHeute" hat
If x.Name = "DatumHeute" Then
x.Text.Story = currentDate
ElseIf Left(x.Name, 10) = "DatumHeute" Then ' Überprüfen, ob der Name der Form mit "DatumHeute" beginnt
ds = Split(x.Name, "(")
FormatString = Left(ds(1), Len(ds(1)) - 1)
x.Text.Story = Format$(Date, FormatString)
FormatString = ""
End If
Next
' Dokument speichern
ActiveDocument.Save
PDFName = DateiDialog
If PDFName = "" Then Exit Sub 'Abbrechen falls kein Name übergeben wurde
If Not PDFEinst.ShowDialog Then Exit Sub 'Abbrechen falls Abbrechen gewählt wurde
ActiveDocument.PublishToPDF PDFName
End SubFalls es mit Deiner Version nicht klappt, melde Dich noch einmal.
Es könnte nützlich sein, Deine Version in der Signatur zu erwähnen.
Gruß
Koter
RE: Automatische aktuelle Datumsangabe - siggimitbart - 05.11.2024
Nochmal herzlichen Dank, das funktioniert bisher hervorragend - wir nutzen das jeden Tag.
Wäre es möglich, folgendes zu ergänzen:
Eine andere Variable die die Projektnummer angibt, sollte im besten fall beim Export auch automatisch ausgefüllt werden. Die Projektnummer könnte man aus dem Dateinamen beziehen. Wenn ich ein neues Dokument erstelle benenne ich es mit der Projektnummer. Die Projektnummer sieht dann so aus "WER-1234" Der Dateiname sieht dann so aus "WER-1234_Produktion". Man könnte also immer die ersten Ziffern des Dateinamen bis zum ersten Unterstrich verwenden. Der Ebenenname kann dann "Projekt" sein.
Würde mich freuen, wenn das möglich wäre.
RE: Automatische aktuelle Datumsangabe - koter - 26.01.2025
Hallo Siggi,
ein frohes neues Jahr!
Die Ergänzung:
Code:
Sub UpdateDateAndExport4()
Dim PDFEinst As PDFVBASettings
Dim currentDate As String, PDFName As String, FormatString As String, ProjektNr As String, Dateiname As String
Dim x As Shape
Dim s As Page
Dim xR As ShapeRange, xRall As New ShapeRange, xProjAlle As New ShapeRange
Dim ds() As String
If Documents.Count < 1 Then Exit Sub 'Abbrechen falls kein Dokument vorhanden ist
Set PDFEinst = ActiveDocument.PDFSettings
' Aktuelles Datum im Format "DD.MM.YY"
currentDate = Format(Date, "DD.MM.YY")
ProjektNr = Projektnummer(True)
For Each s In ActiveDocument.Pages 'Auf allen Seiten suchen
Set xR = s.Shapes.FindShapes(Query:="@com.name.StartsWith('DatumHeute')")
xRall.AddRange xR
Next
For Each s In ActiveDocument.Pages 'Auf allen Seiten suchen
Set xR = s.Shapes.FindShapes(Query:="@com.name.StartsWith('ProjektNr')")
xProjAlle.AddRange xR
Next
For Each x In xRall
' Überprüfen, ob die Form den Namen "DatumHeute" hat
If x.Name = "DatumHeute" Then
x.Text.Story = currentDate
ElseIf Left(x.Name, 10) = "DatumHeute" Then ' Überprüfen, ob der Name der Form mit "DatumHeute" beginnt
ds = Split(x.Name, "(")
FormatString = Left(ds(1), Len(ds(1)) - 1)
x.Text.Story = Format$(Date, FormatString)
FormatString = ""
End If
Next
For Each x In xProjAlle
' Überprüfen, ob die Form den Namen "ProjektNr" hat
If x.Name = "ProjektNr" Then
x.Text.Story = ProjektNr
End If
Next
' Dokument speichern
ActiveDocument.Save
PDFName = DateiDialog
If PDFName = "" Then Exit Sub 'Abbrechen falls kein Name übergeben wurde
If Not PDFEinst.ShowDialog Then Exit Sub 'Abbrechen falls Abbrechen gewählt wurde
ActiveDocument.PublishToPDF PDFName
End Sub
Function DateiDialog() As String
Dim CST As CorelScriptTools
Dim CDRN As String, DN As String, RN As String
Dim Antw
Set CST = CorelScriptTools
DN = ActiveDocument.Name
DN = Left(DN, Len(DN) - 3) & "pdf"
RN = CST.GetFileBox("(PDF)|*.pdf", "Als PDF freigeben", 1, DN)
If Len(RN) < 1 Then DateiDialog = RN: Exit Function
If Len(Dir(RN)) > 0 Then
Antw = MsgBox("Soll die bestehende Datei überschrieben werden?", vbQuestion + vbYesNo, "Datei überschreiben")
DateiDialog = ""
If Antw = vbYes Then
DateiDialog = RN
End If
Else
DateiDialog = RN
End If
End Function
Function Projektnummer(NurNummer As Boolean) As String
Dim Dateiname As String, ProjektNrMit As String, ProjektNrOhne As String
Dim ds() As String
Dateiname = ActiveDocument.FileName
Debug.Print Dateiname
ds = Split(Dateiname, "_")
ProjektNrMit = ds(0)
ds = Split(ProjektNrMit, "-")
ProjektNrOhne = ds(1)
If NurNummer Then
Projektnummer = ProjektNrOhne
Else
Projektnummer = ProjektNrMit
End If
End FunctionIch habe nicht genau verstanden, ob der Suffix (WER-) auch eingetragen werden soll.
Falls ja, ändere die Zeile
ProjektNr = Projektnummer(True)
in
ProjektNr = Projektnummer(False)
Gruß
Koter
RE: Automatische aktuelle Datumsangabe - siggimitbart - 14.03.2025
@koter
Herzlichen Dank fürs erneute Coden/Koten!
Es funktioniert hervorragend.
Was denkst du, was muss ich lernen, um diese Sprache auch so gut zu beherrschen und wie kann ich das lernen?
Würde das gerne selbst machen können.
Beste Grüße
RE: Automatische aktuelle Datumsangabe - koter - 16.03.2025
Hallo Siggi,
was Du zuerst lernen musst, ist natürlich die Sprache: VBA.
Dann musst Du Dich mit den Objekten, deren Eigenschaften und Methoden beschäftigen.
Objekte in CorelDraw sind z.B. Ellipsen, Text, Ebenen, Seiten usw.
VBA ist von Microsoft und hauptsächlich für deren Office-Anwendungen entwickelt worden.
Eine gute Einführung gibt es auf https://www.vba-tutorial.de/.
Die Beispiele auf der Seite beziehen sich natürlich auf Microsoft-Office-Objekte.
Die Elemente der Sprache unterscheiden sich aber nicht von der in CorelDraw (es ist ja die selbe).
Was sich unterscheidet sind die Objekte.
Der „Macro Programming Guide“ wird von Corel als PDF mitgeliefert.
Dort findest Du viel zu den Corel-Objekten.
Eine weitere Quelle ist die VBA-Hilfe (F1-Taste).
Wie Du am besten lernst, musst Du selbst entscheiden.
Die Quellen von Anfang bis Ende durchzuackern ist eine sichere aber langwierige Methode.
Falls Du das VBA-Tutorial benutzen willst, solltest Du es bis zum Kapitel „Ablaufsteuerung“ durchlesen.
Dann hast Du eine gute Grundlage, um in VBA Corel-Objekte zu verwenden.
Die Corel-Objekte: Dokument (Document), Seite (Page) und Ebene (Layer) solltest Du auf jeden Fall kennen.
Danach kannst Du Dich erst einmal auf die Objekte beschränken, die Du für Deine Arbeit am häufigsten brauchst.
Viel Spaß und Erfolg!
Gruß
Koter