Suchen und Ersetzen fehlt in 2023 SE?

[koter]

Hallo Martin,

...Dann muss ich wohl damit leben

Falls VBA bei Deiner Version normal funktioniert,
könnte man einige Suchfunktionen damit erstellen.

Falls Dich das interessiert, kannst Du diesen Code testen:

Code:

Sub GrafikTextSuche()
   Dim sT As String, qT As String
   Dim sTxt As Shape
   Dim sr As ShapeRange
   Dim tSel As TextRange
   Dim tPos As Long
   Dim ng As Boolean
   
   ng = True
   sT = InputBox("Suchtext:", "Grafiktext durchsuchen")
   If sT = "" Then Exit Sub
   ActiveTool = cdrToolPick
   ActiveSelectionRange.RemoveFromSelection
   Set sr = ActivePage.Shapes.FindShapes(Query:="@type = 'text:artistic'")
   For Each sTxt In sr
       Set tSel = sTxt.Text.Story
       tPos = InStr(1, tSel, sT, vbTextCompare)
       If tPos > 0 Then
           tSel.SetRange tPos - 1, Len(sT) + tPos - 1
           sTxt.Text.BeginEdit
           tSel.Select
           ng = False
           Exit For
       End If
   Next
   If ng Then MsgBox "nicht gefunden", , " "
End Sub

Das Makro durchsucht die Grafiktexte der aktiven Seite nach einem bestimmten Text
und markiert die erste Fundstelle, falls der Text gefunden wurde.
(Erstellt mit X7)

Gruß

Koter