Kreis erhält nach Export über Makro als DXF sehr viele Knotenpunkte

[Olaf]

Hallo liebes Forum,

ich möchte ein Objekt (einfacher  Kreis) aus Corel als DXF exportieren, das funktioniert über ein Makro auch sehr gut. Leider besteht der Kreis aber dann aus sehr vielen einzelnen Strichen und sehr vielen Knotenpunkten (20+) und ist dadurch eckig. Wenn ich den gleichen Kreis "per Hand" markiere und dann als DXF exportiere ist er richtig kreisrund und hat nur einen 1-4 Knpotenpunkte.

Daher muss das Problem an dem Exportcode im Makro liegen, leider sehe ich es aber icht... hat jemand eine Idee?

Code:

Option Explicit
Sub ExportDXF()
   Dim expflt As ExportFilter
   Dim l As Layer
   Dim Pfad As String, Dateiname As String
   Dim Anzahl As Integer
       
   For Each l In ActivePage.Layers: l.Printable = False: Next  'Alle Ebenen nicht druckbar schalten
   ActivePage.Layers("Platten").Printable = False    'Ebene druckbar schalten
   ActivePage.Layers("Export").Printable = True    'Ebene druckbar schalten
   Pfad = "\\hb-dc01\work\Hauptordner_FERTIGUNG\_3_LASER\Sonderanfertigung\"
   Anzahl = Dialog1.TextBox7 'Anzahl frtelegen
   Dateiname = Dialog1.TextBox6 'Dateiname festlegen
   Dateiname = Pfad & Dateiname & Replace("_Stck_X.dxf", "X", Anzahl) 'Dateiname vervollständigen und Anzahl einfügen
   
   Set expflt = ActiveDocument.ExportEx(Dateiname, cdrDXF)  'Exportfilter setzen
   With expflt
       .Version = 4 'DXF Version festlegen
       .Units = cdrMillimeter ' Maßeinheit festlegen
       .Finish ' Filter ausführen
   End With
End Sub

Vielen Dank im voraus für  Eure Hilfe.

Gruß

Olaf

[koter]

Hallo Olaf,

ändere im Makro die DXF-Version von 4 auf 11 und versuche ob es dann klappt.

Gruß

Koter

[Olaf]

Hallo Koter,

vielen Dank für Deine schnelle Hilfe, es funtkioniert mit dem Wechsel der DXF Version. Der Kreis ist nun so wie er sein soll. Leider hat sich dadurch aber auch ergeben das der Befehl

Code:

ActivePage.Layers("Platten").Printable = False

ignoriert wird und er beide Ebenden (Platten + Export) exportiert. Ich hatte testweise auch die DXF VErsion 10 und 9 gestestet, da ist es das gleiche. Bei Version 8 klappt es, leider ist der exportierte Kreis dann wieder eckig wie bei Version 4.

Gruß

Olaf

[koter]

Hallo Olaf,

dass der Filter ab Version 9 die Einstellungen ignoriert ist ärgerlich.
Mir war das bis jetzt noch nicht aufgefallen. Eine Lösung habe ich leider nicht.

Du kannst versuchen das Problem zu umgehen, indem Du vom Makro eine Auswahl erstellen und exportieren lässt:

Code:

  ActivePage.Shapes.FindShapes(Query:="@com.layer.printable='true'").CreateSelection 'Objekte auf druckbaren Ebenen auswählen
  Set expflt = ActiveDocument.ExportEx(Dateiname, cdrDXF, cdrSelection) 'Exportfilter setzen
  With expflt
      .Version = 11 'DXF Version festlegen
      .Units = cdrMillimeter ' Maßeinheit festlegen
      .Finish ' Filter ausführen
  End With

Die erste Zeile aus dem Code-Fragment musst Du einfügen und die zweite entsprechend ändern.
Mit X7 klappt das, ich hoffe mit Deiner Version auch.

Gruß

Koter

[Olaf]

Hallo Koter,

es funktioniert hervorragend, ich sage mal wieder vielen Dank für Deine professionelle und schnelle Unterstützung, das it eine große Hilfe für uns.

Gruß

Olaf