Fehlerhafte Knoten-Griffe automatisch finden

[asterix]

falsch reinkopiert, hier der ganze Teil, bin echt kein Makro-Profi, ich hoffe, ich habe das nun richtig erfasst:

Code:

Sub kurzegriffe()
    Dim s As Shape
    Dim c As Curve
    Dim sp As SubPath
    Dim sgF As Segment, sgL As Segment
    Dim minL As Double
    ActiveDocument.Unit = cdrMillimeter

    For Each s In ActiveLayer.Shapes
        minL = s.Outline.Width / 5
        Set c = s.Curve
        For Each sp In c.SubPaths
            Set sgF = sp.Segments.First
            Set sgL = sp.Segments.Last
            If sgF.StartingControlPointLength < minL Then
                Markierung sgF.StartingControlPointX, sgF.StartingControlPointY, True
            End If
            If sgL.EndingControlPointLength < minL Then
                Markierung sgL.EndingControlPointX, sgL.EndingControlPointY
            End If
        Next
    Next
End Sub

Sub Markierung(x As Double, y As Double, Optional red As Boolean = False)
    Dim s As Shape
    Dim L As Layer, LA As Layer
    Set LA = ActiveLayer
    If LayerExists("Steuerpunktmarkierung") Then
        Set L = ActivePage.Layers("Steuerpunktmarkierung")
    Else
        Set L = ActivePage.CreateLayer("Steuerpunktmarkierung")
    End If
    Set s = L.CreateEllipse2(x, y, 2)
    If red Then
        s.Outline.Color.RGBAssign 255, 0, 0
    Else
        s.Outline.Color.RGBAssign 0, 100, 0
    End If
    s.Outline.Width = 0.5
    LA.Activate
End Sub

Public Function LayerExists(ByVal strLayerName As String) As Boolean
    Dim objLayer As Layer
    On Error Resume Next
    Set objLayer = ActivePage.Layers(strLayerName)
    LayerExists = Not objLayer Is Nothing
End Function

Wie gesagt, eine Verlängerung der Griffe wäre wünschenswert, weil ich dann besser dran komme und ändern kann. 

(Eine automatische Drehung, wenn falsch gedreht, wäre natürlich das Optimum, aber leider nicht so automatisiert möglich, das muss ich erst nochmal genauer ansehen.)